看股吧 www.kanguba.com [今日大盘指数 欧美全球股市行情 股票公式查询网站] 手机APP下载 | 手机访问 | 加入收藏 | 保存到桌面
看股吧
看股吧股票网-今日大盘指数 欧美全球股市行情 股票公式查询网站
股票查询: 行情分析 DDX指标 走势点评 股票公告 大事 主力持仓 股权质押 分红 大小非 十大股东 股本结构 高管持股 研报 高管 主营 龙虎榜 股吧
当前位置: 看股吧 > 股票公式 > 通达信公式
股票公式搜索:

通达信突破趋势线主图指标公式

2021/1/8 18:18:38

{连结MACD相邻红绿柱区间内高低点画趋势线 通达信}
DIFF:=EMA(CLOSE,12)-EMA(CLOSE,26);
DEA:=EMA(DIFF,9);
N1:=BARSLAST(CROSS(DIFF,DEA))+1;{最近一次满足条件DIFF上穿DEA的K线到当前的距离}
N2:=BARSLAST(CROSS(DEA,DIFF))+1;{最近一次满足条件DIFF下穿DEA的K线到当前的距离}
{当前是DIFF>DEA的状态,连结最近两个DIFF>DEA区间(不包含当前区间)内最高点的趋势线}
A1:=BACKSET(ISLASTBAR && N1<N2,REF(REF(HHVBARS(H,N1)+1,N2),N2)+REF(N2,N2)+N2);
B1:=BACKSET(ISLASTBAR && N1<N2,REF(HHVBARS(H,N1),N2)+N2+1);
DRAWLINE(CROSS(A1,0.5),H,CROSS(B1,0.5),H,1),COLORRED;
{当前是DIFF>DEA的状态,连结最近两个DIFF<DEA区间内最低点的趋势线}
A2:=BACKSET(ISLASTBAR && N1<N2,REF(REF(LLVBARS(L,N2)+1,N1),N2)+REF(N1,N2)+N2);
B2:=BACKSET(ISLASTBAR && N1<N2,REF(LLVBARS(L,N2)+1,N1)+N1);
DRAWLINE(CROSS(A2,0.5),L,CROSS(B2,0.5),L,1),COLORGREEN;
{当前是DIFF<DEA的状态,连结最近两个DIFF<DEA区间(不包含当前区间)内最低点的趋势线}
A3:=BACKSET(ISLASTBAR && N1>N2,REF(REF(LLVBARS(L,N2)+1,N1),N1)+REF(N1,N1)+N1);
B3:=BACKSET(ISLASTBAR && N1>N2,REF(LLVBARS(L,N2),N1)+N1+1);
DRAWLINE(CROSS(A3,0.5),L,CROSS(B3,0.5),L,1),COLORGREEN;
{当前是DIFF<DEA的状态,连结最近两个DIFF>DEA区间内最高点的趋势线}
A4:=BACKSET(ISLASTBAR && N1>N2,REF(REF(HHVBARS(H,N1)+1,N2),N1)+REF(N2,N1)+N1);
B4:=BACKSET(ISLASTBAR && N1>N2,REF(HHVBARS(H,N1)+1,N2)+N2);
DRAWLINE(CROSS(A4,0.5),H,CROSS(B4,0.5),H,1),COLORRED;

看股吧公 式 ww w.kanguba.com

其它股票公式列表
看股吧查股导航:个股行情分析查询 股票DDX指标查询 走势点评 股票公告查询 大事提醒 股权质押查询 股票分红查询 解禁查询 高管持股 高管查询
金通灵 300091+2.30% 公告 DDX在线 走势点评 限售解禁 高管 股权质押
沧州大化 600230+2.29% 公告 DDX在线 走势点评 限售解禁 高管 股权质押
中原证券 601375+2.29% 公告 DDX在线 走势点评 限售解禁 高管 股权质押
美丽生态 000010+2.29% 公告 DDX在线 走势点评 限售解禁 高管 股权质押
九洲集团 300040+2.28% 公告 DDX在线 走势点评 限售解禁 高管 股权质押
中国中铁 601390+2.28% 公告 DDX在线 走势点评 限售解禁 高管 股权质押
华电重工 601226+2.28% 公告 DDX在线 走势点评 限售解禁 高管 股权质押
安徽建工 600502+2.27% 公告 DDX在线 走势点评 限售解禁 高管 股权质押
中信国安 000839+2.27% 公告 DDX在线 走势点评 限售解禁 高管 股权质押
汇金科技 300561+2.26% 公告 DDX在线 走势点评 限售解禁 高管 股权质押
看股网力求但不保证数据的完全准确,不对因网站全部内容或部分内容而引致的盈亏承担任何责任,本站所有内容仅供参考。
本站不提供任何股票服务,站内广告不代表看股吧的观点,由此引起的一切法律责任均与本站无关,请股民自行识别判断,谨慎投资,预防上当受骗!
联系我们:nlfen9@hotmail.com
手机版(手机访问当前页面) | 手机APP下载 | 电脑端(适合电脑或大屏用户)